Excel 中比 Vlookup 更强大的 INDEX 和 MATCH 函数

原文标题：《比 Vlookup 更强大！这个函数组合，用过的人都说香，错过后悔一个亿！》

大家好，我是懂点 Excel 的小兰~

在 Excel 中，INDEX 和 MATCH 函数是一对万金油查找函数公式，两者配合，能够发挥出巨大的作用！

MATCH 函数负责找位置，然后告诉 INDEX 位置，INDEX 就去把东西抓过来，好比侦探和警察的关系。

我们来看个简单的例子。

Q：现在需要从左侧表格里，找到柚子的销量并填写在 E2 单元格，该怎么做？

A：先用 MATCH 函数找到柚子在 A 列中的位置，公式如下：

=MATCH(D2,A1:A30,0)

结果为 13。

这就说明，在 A1:A30 这个区域中，柚子在第 13 个位置。

然后在 MATCH 函数外面，嵌套 INDEX 函数，公式如下：

=INDEX(B1:B30,MATCH(D2,A1:A30,0))

结果为 231。这就是柚子的销量。

公式意思也很好理解，在 B1:B30 这个区域里，找到第 13 行的数据，也就是 231。

上面这是一个比较简单的例子，但是也能看出 INDEX+MATCH 这对组合函数在查找数据方面，能够发挥出的作用。

以下，我还准备了 6 个 INDEX+MATCH 函数的经典用法，助力大家更快掌握这两个函数。

1、反向查找

反向查找：查找的结果信息在所需查找条件列的前面。

如下图：根据 B 列的水果名称，查找 A 列的编号。

公式：

=INDEX(A2:A30,MATCH(E2,B2:B30,0))

公式说明：和前面举例的正向查找公式区别不大，唯一需要注意的是查找区域的变化。

相比 VLOOKUP 函数还需要借助 IF 函数构造数组来说，INDEX+MATCH 更容易理解，也更好操作。

2、交叉查找

交叉查找引用数据，如下图，根据「列号」和「行号」，查找结果信息。

公式：

=INDEX(B2:F11,MATCH(I1,A2:A11,0),MATCH(I2,B1:F1,0))

公式说明：

用第一个 MATCH 函数查找「第 2 排」在 A2:A11 中的位置，结果为 2；

用第二个 MATCH 函数查找「第 3 列」在 B2:F2 中的位置，结果为 3；

最后用 INDEX 函数在 B2:F11 区域中查找。

3、一对多查找

如下图，根据「名称」，查找一月、二月、三月的「销售额」。

公式：

=INDEX($B$2:$D$30,MATCH($F3,$A$2:$A$30,0),MATCH(G$2,$B$1:$D$1,0))

公式说明：对比一下前面提到的交叉查询公式，可以发现，这两个公式原理其实是一样的，只是增加了绝对引用和混合引用。

4、多条件查找

比如，根据两个条件「月份」和「名称」，查找「销量」。

公式：

=INDEX($C$2:$C$21,MATCH(E3&F3,$A$2:$A$21&$B$2:$B$22,0))

公式说明：利用 & 符号将查找条件，查找区域组合在一起，再按正向查找的方法进行查找。

5、区间查找

如果查找值处于某一个区间内，就返回对应的目标值。

如下图，需要根据业绩区间来计算员工的奖金数。

公式：

=INDEX(I2:I5,MATCH(E2,{0,41,81,121},1))

公式说明：这个公式需要注意第二和第三参数的应用。如果第三参数是 1 或者省略，MATCH 函数将查找小于或等于第一参数的最大值，并且第二参数中的值必须是升序排序。

6、模糊查找

模糊查找：通过结合使用通配符（「？」问号和「*」星号）来实现查找目标值。

如下图，需要查找最后一个字符是「瓜」，一共三个字符的水果的销量是多少。

公式：

=INDEX(C2:C30,MATCH("??"&E2,B2:B30,0))

公式说明：

「？」问号通配符，代表任意单个字符。「*」星号通配符，代表匹配任意多个字符。

这里我们用了两个「？？」问号，就代表任意两个字符。

PS：问号和星号必须使用英文半角的！

7、写在最后

最后给大家做个小小的总结~

INDEX 和 MATCH 函数常见使用方法有以下 7 种：

正 / 反向查找

交叉查找

一对多查找

多条件查找

区间查找

模糊查找

INDEX 和 MATCH 函数的作用非常之强大，祝愿大家早日掌握！

本文来自微信公众号：秋叶 Excel （ID：excel100），作者：小兰